Display different Roomtemperature on MagicMirror

Xilef

wishmaster270

@Xilef
ESP8266 is a good choice. I prefer ESP32 cause it has more power but does not need that much more energy. You have a lot more GPIOs with a ESP32 than a with the ESP8266.

I can provide you a ESP32 sketch which is ready to flash and only needs the Wifi-SSID, Wifi-Password and the MQTT parameters configured.
I use the Arduino IDE to flash the boards.

Xilef

@wishmaster270 thanks

As I understand it, something like this is my target:

And i would need:

ESP32
DHT11-Sensor Problem with this Sensor is the accuracy i think, but if it works I can swap them out I guess
BreadBoard

And as Powersupply something with 5V and 1-1,5A right?

I would probably do it like this guy on youtube https://www.youtube.com/watch?v=ebJpXs2-WgM&list=PLUwa0e4GQGhS6KCSbLAQGog4_Z7eIWOm3&index=3

And from the ESP32-Website the MagicMirror should be able to read the data and display it

wishmaster270

@Xilef
You need a ESP32 ( I use a D1 Mini but nearly everyone should be fine)
You need a Temperature and Humidity Sensor (BME280 and HTU21 are a lot more accurate and use I2c to communicate with the controller.
A Power supply with 5V 1A should be more than enough.

That’s how I display my values…
Screenshot_20221126_234807_bVNC Pro.jpg

The first three are ESP32 the others my thermostats.

JerryP

@wishmaster270

nice…

Xilef

@wishmaster270 Thats exactly what i had in mind

The BME280 sensors on amazon are a litte expensive so Im think Im order 3 form this shop They have 5 Pins but I think this will work to, on Aliexpress its even cheaper but i have no experience with the shop, and 1-3€ difference is ok i guess

And I wanted to ask what power supply you use e.g. just a cell phone charger?
I think im gona go with this one and hope that it doesnt explode

So if I have everything right this is my shopping list:
ESP32
BME280
Power Supply
BreadBoard

And then I just have to figure out the programming

Xilef

Edit: With Power Supply i mean this one: https://www.amazon.de/gp/product/B08LMFBV55/ref=ox_sc_act_title_2?smid=A1XVC08L2WVJCV&psc=1

wishmaster270

@Xilef Hi, the list sounds good. I use old mobile chargers to power the boards. I have heard that some had problems with mobile chargers but I had no problems for years now.

Xilef

Hey im back @wishmaster270

my parts arrived, and after 5 hours of Troubleshooting i was able to achieve this: (with the help of this tutorial)

Now i need just a little bit help to display the Temperature and Humidity on my mirror

wishmaster270

@Xilef
Hi,
thats great news.
The screenshot shows that you setup the ESP32 and the sensor correctly.
The main problem is that the ESP now displays a webpage.
There are two possible ways now. Either you embed the webpage (as it is) into the mirror with a module like MMM-EmbedURL or to get the ESP to display the data machine readable.
Maybe the sketch you flashed to the ESP already contains a way to read the data in a different format? Which one did you use?

Edit: I think it is this one, am i right? Then there is no easy way.
I think i can provide a sketch that is more “mirror friendly” but you will need to set a static IP for the ESP. Is this ok for you?

You will need to change to your needs:

##ADD_WIFI_SSID_HERE
##ADD_WIFI_PASSWORD_HERE
IPAddress local_IP(192, 168, 0, 2);
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0);
IPAddress primaryDNS(192, 168, 0, 1);

#include <WiFi.h>
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

const char* ssid     = "##ADD_WIFI_SSID_HERE";
const char* password = "##ADD_WIFI_PASSWORD_HERE";

//ENTER STATIC IP OF THE ESP32 BOARD HERE
IPAddress local_IP(192, 168, 0, 2);
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0);
IPAddress primaryDNS(192, 168, 0, 1);
IPAddress secondaryDNS(8, 8, 8, 8);

Adafruit_BME280 bme;

WiFiServer server(80);

void setup()
{
  Wire.begin();
  Serial.begin(115200);

  if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
    Serial.println("STA Failed to configure");
  }

  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected!");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  Serial.print("ESP Mac Address: ");
  Serial.println(WiFi.macAddress());
  Serial.print("Subnet Mask: ");
  Serial.println(WiFi.subnetMask());
  Serial.print("Gateway IP: ");
  Serial.println(WiFi.gatewayIP());
  Serial.print("DNS: ");
  Serial.println(WiFi.dnsIP());

  if (!bme.begin(0x76);) {
    Serial.println("Couldn't find sensor!");
    while (1);
  }

  server.begin();
}

void loop()
{
  float temp = bme.readTemperature();
  float tempf = temp * 1.8 + 32;
  float rel_hum = bme.readHumidity();

  WiFiClient client = server.available();
  if (client) {
    Serial.println("New Client."); 
    client.println("{");
    client.print("  \"temperature_c\": ");
    client.print(temp);
    client.println(",");
    client.print("  \"temperature_f\": ");
    client.print(tempf);
    client.println(",");
    client.print("  \"humidity\": ");
    client.print(rel_hum);
    client.println(",");
    client.println("  \"error\": false");
    client.println("}");
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
  delay(100);
}

You can use netcat to fetch the data:

/bin/nc -w3 THE_IP_OF_THE_ESP 80

And the result will be something like:

{
   "humidity": 32.61236572265625,
   "temperature_c": 25.50150878906249, 
   "temperature_f": 77.9027158203125, 
   "error": false
}

This kind of JSON object then can be read by my MMM-Temperature module.

sdetweil

@wishmaster270 I created a sketch for my 8266, which is a json get. returns current temp and humidity.

then I just fetch it when I want, similar to what u did

wishmaster270

@sdetweil Hi Sam, i was to slow with editing my post. The Sketch i provided does exactly that.

Xilef

@wishmaster270 i think thats a good way to to it

@wishmaster270 said in Display different Roomtemperature on MagicMirror:

but you will need to set a static IP for the ESP

So i need to set it manually in the router settings?

@wishmaster270 said in Display different Roomtemperature on MagicMirror:

#include <WiFi.h>…

Thats what i need to flash on the esp , right?

@wishmaster270 said in Display different Roomtemperature on MagicMirror:

/bin/nc -w3 THE_IP_OF_THE_ESP 80

idk what that’s supposed to be for

and you have to explain to me in more detail what I should add to the IPs

wishmaster270

@Xilef
You can but do not have to set the ip in the router. You either need a free address in the range that is NOT used by your routers DHCP server or maybe there is a setting to provide the device always with the same IP in your router. You then can set this IP for the ESP (as it is not used for any other DHCP device in the future then.

the local_ip in the sketch is the IP you choose for the ESP (attention the numbers are separated with , and NOT ..
the gateway is the IP of your router
the subnet depends on your network but 255,255,255,0 will be fine in the most cases
the primaryDNS is usually the IP of you router

yes the “include …” part is the one to be flashed to the ESP.

After you flashed the new Sketch to the ESP and booted it you can use the nc command to fetch the data from the shell of the mirror. The temperature module uses this command to get the data so you can make sure to see if it works without the need to install the module first.

Xilef

@wishmaster270 i guess thats what i need

“Always assign the same IPv4 address to this network device.”

And for the WIFI SSID and Passwort, behind the 2 ## right?

and where do i need to use the nc command? on the esp32 or on the raspberry pi?

wishmaster270

@Xilef
Perfect. This is the right setting.

You need to replace the ##, too.
It will look something like:

const char* ssid     = "MY_WIFI_NETWORK";
const char* password = "123ABC456";

IPAddress local_IP(192, 168, 178, 106);
IPAddress gateway(192, 168, 178, 1);
IPAddress subnet(255, 255, 255, 0);
IPAddress primaryDNS(192, 168, 178, 1);
IPAddress secondaryDNS(8, 8, 8, 8);

To check if everything is set up correctly you can run:

/bin/nc -w3 192.168.178.106 80

Xilef

@wishmaster270 the “/bin/nc -w3 192.168.178.106 80” command on the serial monitor message line?

:/

I would suggest to remove the clamp behind the ; ??

wishmaster270

@Xilef
Sorry, my fault. You need to change line 52 to:

if (!bme.begin(0x76)) {

Copy&Paste mistake of me

Xilef

@wishmaster270 i installed the module, but i cant display the data

what am i doing wrong, ah the esp32 says he couldnt find a sensor, thats weird
(edit: i tried another one and it worked this time)

wishmaster270

@Xilef
You will need the MMM-Temperature module and not the Embed module as you do not want to display a website but parse the JSON data object and display its contents.
The config will look something like:

		{
			module: "MMM-Temperature",
			position: "bottom_right",
			config: {
				sensors: [
					{
					    name: "ESP",
					    script: "/bin/nc",
					    args: "-w3 192.168.178.106"
                    			},
				]
			},
		},

But you will need to fix the missing sensor first.

Can you please check your wiring and use this sketch instead of the other one. I only removed one line which i do not think is the problem but i can not test the sketch at the moment.

#include <WiFi.h>
#include <Wire.h>
#include <Adafruit_Sensor.h>
#include <Adafruit_BME280.h>

const char* ssid     = "##ADD_WIFI_SSID_HERE";
const char* password = "##ADD_WIFI_PASSWORD_HERE";

//ENTER STATIC IP OF THE ESP32 BOARD HERE
IPAddress local_IP(192, 168, 0, 2);
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0);
IPAddress primaryDNS(192, 168, 0, 1);
IPAddress secondaryDNS(8, 8, 8, 8);

Adafruit_BME280 bme;

WiFiServer server(80);

void setup()
{
  Serial.begin(115200);

  if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
    Serial.println("STA Failed to configure");
  }

  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected!");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  Serial.print("ESP Mac Address: ");
  Serial.println(WiFi.macAddress());
  Serial.print("Subnet Mask: ");
  Serial.println(WiFi.subnetMask());
  Serial.print("Gateway IP: ");
  Serial.println(WiFi.gatewayIP());
  Serial.print("DNS: ");
  Serial.println(WiFi.dnsIP());

  if (!bme.begin(0x76)) {
    Serial.println("Couldn't find sensor!");
    while (1);
  }

  server.begin();
}

void loop()
{
  float temp = bme.readTemperature();
  float tempf = temp * 1.8 + 32;
  float rel_hum = bme.readHumidity();

  WiFiClient client = server.available();
  if (client) {
    Serial.println("New Client."); 
    client.println("{");
    client.print("  \"temperature_c\": ");
    client.print(temp);
    client.println(",");
    client.print("  \"temperature_f\": ");
    client.print(tempf);
    client.println(",");
    client.print("  \"humidity\": ");
    client.print(rel_hum);
    client.println(",");
    client.println("  \"error\": false");
    client.println("}");
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
  delay(100);
}